' Because this partial implementation of VBSCRIPT doesn't support basic programming features like Functions or Subs everything has to be top down inline code.
' I'm going to have to see if I can't use Visual Studio and the vMixAPI.DLL


'Countdown to Service start Script

' vMix Inputs - All will be referenced using their unique "key" (GUID) which will only change if the input is deleted and then added again, otherwise changing the name or input number will not affect this script
Dim CountdownScreen as string = "17abeafe-9243-45a7-879d-94491046b873"
Dim CountdownTitle as string = "3e500d73-872c-4841-aa5c-67ebbf46d486"
Dim CountdownTitleText as string = "Sunday Service begins in "


Dim ServiceTime as string
Dim StreamingStartTime as string

Dim dtServiceTime as DateTime
Dim dtStreamingStartTime as DateTime 

Dim Streaming as boolean = false

CountdownTitleText = "Sunday Service begins in "
dtServiceTime = new DateTime(Datetime.Now.Year, DateTime.Now.Month, DateTime.Now.Day ,10,00,00)
dtStreamingStartTime = new DateTime(Datetime.Now.Year, DateTime.Now.Month, DateTime.Now.Day ,09,45,00)

StreamingStartTime = dtStreamingStartTime.ToString("hh:mm")
ServiceTime = dtServiceTime.ToString("hh:mm")
console.writeline ( "ServiceTime=" & ServiceTime & " Stream starting time=" & StreamingStartTime & " Current time=" & DateTime.Now.ToString("hh:mm"))

'		Main timer Loop
'
'			We check for everything that needs to happen during the countdown in this loop:
'				1.	End of the countdown
'				2.	Time to start streaming (15 mins before end of countdown as of this comment being written)
'

Do While True
	If ServiceTime = DateTime.Now.ToString("hh:mm") Then
		' The times match so exit the loop!
		Exit do
    End If
    If StreamingStartTime = DateTime.Now.ToString("hh:mm") and (not Streaming) Then
		' Time to start the streaming
		API.Function("StartStreaming","0")
		Streaming = true
	End If
	' Here we will update the countdown time in the "HeadlineText" of the countdown screen
	
	Dim tsHowLong as TimeSpan = dtServiceTime - DateTime.Now
	Dim stHowLong as String = tsHowLong.ToString.Substring(0,8)
	If stHowLong.Substring(0,2) = "00" Then
		stHowLong = stHowLong.Substring(3,5)
	End If
	API.Function("SetText",Input:=CountdownTitle,SelectedName:="Headline.Text",Value:= CountdownTitleText & stHowLong)
	'console.writeline("Time Left = " & TimeLeft & " Hours left " & Hoursleft & " Minutes left " & CStr(MinutesLeft) & " Seconds left " & Secondsleft)
	sleep(1000)  ' Sleep for one second
Loop

Console.writeline("Starting service")